Zandronum

SwordGrunt wrote:"All arrays must have script (New from 2.8.1), map, global or world scope (the last two are special case arrays though)."

Script arrays are not supported by Zandronum so you'll get odd results attempting to use them. Why not just declare them as map arrays, outside your script?

Perhaps if you share a bit more on what you're using the array for, I could tell you whether or not you really want the script scope on your variable. Usually that's only needed for scripts with multiple instances called (ACS_ExecuteAlways and derivatives) where each instance can use the variable without affecting the others (while I've personally never used it this way, I remember seeing a script that did, I believe it was ZDoom Wars' health bar script).

#include "zcommon.acs"
#define maxCount 350

script 1 ENTER
{
    Sector_SetFade(2, 25, 25, 25); // spooky fog
    Sector_SetDamage(2, 20, MOD_POISON);
}

script 2 ENTER
{
    int count = 0;
    int toSpawn = 1;
    while(true)
    {
        if(count < maxCount)
        {
            count++;
            HudMessage(s:"Time until next spawn:", d:(maxCount - count)/35; HUDMSG_PLAIN, 1, CR_BLUE, 0.5, 0.0, 0);
            Delay(1);
        }
        else // NOTE: Everything commented out is broken, fix it later/never
        {
            int spawned = 0;
            // log(s:"Setting up demons array");
            // int demons[10] = {UniqueTID(), UniqueTID(), UniqueTID(), UniqueTID(), UniqueTID(), UniqueTID(), UniqueTID(), UniqueTID(), UniqueTID(), UniqueTID()};
            while(spawned < toSpawn)
            {
                // log(s:"Setting up newID");
                int newID = UniqueTID();
                spawned += SpawnSpot("Demon", 1, newID);
                // TODO: Change demon stuff
                Delay(1);
            }
            toSpawn += 1;
            count = 0;
        }
    }
}

SwordGrunt wrote:The most important thing is to change those ENTER scripts to OPEN, since enter is executed every time a player joins the game with that player as the activator, and these scripts are clearly only supposed to be called once at game start with the activator being the world (exactly what open scripts are).

So you're delaying the waves by putting 10 seconds between each, then attempting to spawn a Demon every tic on the spot of ID 1 with an unique TID (which is a ZDoom 2.7.1 function if I'm not mistaken, meaning it's not supported by Zandronum 2.1!)

Here's my version (hopefully simple to understand) of your script:

Code: Select all

#include "zcommon.acs"

#define maxcount 10                // in seconds
#define maxdemoncount 10      // number of demons to spawn
#define baseid 25                     // Demons will have TIDs of baseid, baseid+1, baseid+2... baseid+(maxdemoncount - 1)

int demoncount; // if you do not initialize a variable, it defaults to 0. This includes arrays: every value is initialized to 0

script 2 OPEN
{
    for(int count = 0; count < maxcount; count++)
    {
        HudMessage(s:"Time until next spawn: \cd", i:(maxCount - count); HUDMSG_PLAIN, 1, CR_BLUE, 0.5, 0.0, 0);
        Delay(35);
    }

    while(demoncount < maxdemoncount)
    {
        if(SpawnSpot("Demon",1,baseid + demoncount))
            demoncount++;

        Delay(10);
    }

    demoncount = 0;

    restart;
}

SwordGrunt wrote:Does it return proper values in-game? I thought it was a ZDoom 2.7 function but I could be wrong.

There isn't really a reference but new ACS functions are pretty scarce so don't worry about it.

I'd recommend using fixed TID values regardless, that way you can adapt your script later to account for monsters on the field before spawning more via ThingCount, if you want to - a good example would be spawning a Cyberdemon only after all demons have been killed, instead of delaying it by a fixed time frame.

Edward-san wrote:I'd like to clarify that UniqueTID was backported out of sequence, so it is available since 2.1.